Utilizamos cookies propias y de terceros. Al navegar entendemos que aceptas el uso de cookies. +Info.
Política de cookies
Proyecto AjpdSoft

· Inicio
· Buscar
· Contactar
· Cookies
· Descargas
· Foros
· Historia
· Nosotros
· Temas
· Top 10
· Trucos
· Tutoriales
· Usuario
· Wiki

Nick


Contraseña


Nuevo usuario


English

Programacion: Módulo para añadir a aplicación con utilidades de base de datos MySQL en Delphi
Delphi


Os mostramos el código fuente completo de un módulo (formulario o TForm) realizado en Borland (ahora Codegear) Delphi 6: permite mostrar todas las tablas de un catálogo o esquema, descripción de las tablas (campos y tipos de datos), información de las tablas, variables del entorno MySQL, estado de la base de datos, catálogos de MySQL Server, optimización de las tablas, análisis de las tablas, vaciar tablas seleccionadas y reiniciar contador autoincremento, conversión de tipo de tabla a InnoDB, ISAM, MEMORY, MRG_MYISAM, MyISAM.




Objetivo de la Ventana con utilidades para administrar base de datos MySQL

Esta ventana que os mostramos es útil para añadir a vuestras aplicaciones realizadas en Borland (ahora Codegear) Delphi con acceso a MySQL. Os permitirá dotar vuestra aplicación con utilidades que os pueden ser necesarias en cualquier momento. Las opciones que os permitirá esta ventana sobre la base de datos MySQL serán:

  • Script de creación de tablas: esta opción os mostrará para cada tabla la consulta SQL necesaria para crearla (create table ...). Os será muy útil para guardar los script de creación de todas las tablas de vuestra aplicación y poder regenerar el catálogo o esquema en cualquier momento.
  • Tablas: os mostrará todas las tablas de la aplicación.
  • Descripción de las tablas: mostrará por cada tabla los campos que tiene y el tipo de datos de cada campo.
  • Información de las tablas: mostrará el nombre, el tipo de tabla, la fecha de creación, el número de registros, el tamaño de la tabla, el tamaño de los índices, el juego de caracteres, etc.
  • Variables: muestra todas las variables de la base de datos MySQL y su valor. Muy útil para detectar problemas de configuración de MySQL Server.
  • Estado de la Base de Datos: muestra estadísticas actuales de la base de datos: lecturas, eliminaciones, inserciones, tareas, etc.
  • Catálogos: muestra todos los catálogos (esquemas) de la base de datos MySQL Server.
  • Optimizar: permite optimizar las tablas con el comando SQL "optimize table".
  • Analizar: analiza las tablas, comprueba que su estado sea correcto.
  • Vaciar: permite vaciar las tablas seleccionadas. Elimina todos los registros de las tablas seleccionadas y permite reiniciar el contador de autoincremento para que empiece por uno. Esta acción es "peligrosa" por lo que se pedirá confirmación dos veces antes de proceder.
  • Tipo de BD: permite cambiar el tipo de las tablas de la base de datos, admite los siguientes tipos de tabla de MySQL Server: InnoDB, ISAM, MEMORY, MRG_MYISAM, MyISAM.

Con lo cual, con esta utilidad, podremos dotar nuestras aplicaciones de herramientas para el testeo y comprobación de posibles errores, para obtener información muy útil para los desarrolladores y administradores de base de datos, para la preparación de las tablas de la aplicación para un nuevo uso, etc.

 

Cómo se hizo la ventana para administrar MySQL con Delphi

A continuación os mostraremos el código fuente utilizado en cada una de las opciones de esta ventana - módulo. Os servirá por si sólo queréis implementar una o varias de las opciones de esta utilidad.

En primer lugar, utilizando Borland (ahora Codegera) Delphi 6, agregamos un nuevo formulario (TForm) pulsando en "File" - "New" - "Form":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Nuevo formulario

A este formulario agregaremos un PageControl de la paleta de componentes Win32:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - PageControl

Al PageControl anterior le añadiremos todas las pestañas - solapas necesarias para nuestra ventana de administración de MySQL Server, pulsando con el botón derecho sobre el PageControl añadido y seleccionando "New page":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - New Page en el PageControl

En cada pestaña del PageControl iremos añadiendo todos los componentes necesarios Button, RichEdit, Memo, StaticText, ChecBox, etc. El aspecto final será algo así:

  • Pestaña de "Script creación tablas":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Pestaña de Script creación tablas

  • Pestaña de "Optimizar tablas":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Pestaña de Optimizar tablas

  • Pestaña de "Analizar tablas":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Pestaña de Analizar tablas

  • Pestaña de "Vaciar tablas":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Pestaña de Vaciar tablas

  • Pestaña de "Tipo de BD":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Pestaña de Tipo de BD

El código fuente de esta ventana: ver código fuente.

 

El módulo de datos (DataModule)

El formulario anterior está "enlazado" mediante la clausula "USES" con el módulo de datos UnidadModuloDatos. Este módulo será el contenedor de los componentes de acceso a datos necesarios, en nuestro caso hemos usado ZeosDBO:

  • tc2: ZQuery.
  • tc: ZQuery.
  • bd: ZConnection.

Añadiremos un nuevo DataModule, en Delphi, desde el menú "File" - "New" - "DataModule":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Módulo de datos - DataModule

Pulsaremos INTRO ó F4 para mostrar el Object Inspector y en "Name" especificaremos el nombre del DataModule, en nuestro caso "md":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Módulo de datos - DataModule - Nombre

A continuación añadiremos al DataModule los componentes de acceso a datos. En nuestra utilidad hemos utilizado ZeosDBO, es un componente gratuito y Open Source que permite acceso nativo a MySQL Server desde Delphi. Añadiremos dos TZQuery (que llamaremos "tc" y "tc2") y un TZConnection que llamaremos "bd". Los TZQuery" servirán para ejecutar las consultas SQL necesarias, tanto de selección como de modificación de datos. El TZConnection nos permitirá el acceso a MySQL Server.

Desde la pestaña "Zeos Access" de la paleta de componentes añadiremos los ZQuery y el ZConnection:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Zeos Access

Los dos ZQuery irán enlazados con el ZConnection mediante la propiedad "Connection" de ambos:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - TZQuery, TZConnection

 

Añadir la ventana y el módulo de datos a una aplicación Delphi existente

Para añadir este formulario y el módulo de datos a una aplicación existente y poder utilizarlo, abriremos la aplicación desde el menú "File" - "Open project" de Delphi:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Open Project

Seleccionaremos el .dpr del proyecto de nuestra aplicación:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Selección de fichero de proyecto

Desde el menú "Project" pulsaremos en "Add to Project...":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Añadir nueva unidad al proyecto

Seleccionaremos la unidad "UnidadUtilidadesBD.pas" que previamente habremos descargado de esta web:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Añadir nueva unidad al proyecto

De la misma forma agregaremos también la unidad "UnidadModuloDatos.pas":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Añadir nueva unidad al proyecto

Por último, para que la UnidadUtilidadesBD.pas y UnidadModuloDatos.pas queden enlazadas, abriremos el formulario que contiene el PageControl con las pestañas necesarias "" y enlazaremos éste con el DataModule. Pulsando Shift + F12, se abrirá la ventana de los formularios de la aplicación, seleccionaremos el formulario añadido "formUtilidadesBD" y pulsaremos "OK":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Mostrar formulario

Desde el menú "File" - "Use Unit...":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Use unit

Seleccionaremos la unidad que contiene el módulo de datos añadido "UniadModulodatos" y pulsaremos "OK":

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Selección de unidad

Con esto ya tendremos agregado a nuestra aplicación el módulo necesario para que la ventana de utilidades de administración de MySQL funcione. Ahora sólo nos quedará añadir la opción de menú para mostrarla, por ejemplo:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Añadir opción de menú

Con el código:

application.createform(TFormUtilidadesBD, FormUtilidadesBD);
FormUtilidadesBD.showmodal;

Lógicamente, en algún momento, la aplicación deberá preparar el componente "bd" (ZConnection) del DataModule "md" para conectarlo a MySQL, un ejemplo del código de preparación de este componente:

    md.bd.Disconnect;

    md.bd.Database := txtBDBD.Text;
    md.bd.User := txtBDUsuario.Text;
    md.bd.Password := txtBDContrasena.Text;
    md.bd.HostName := txtBDServidor.Text;
    md.bd.Port := strtoint(txtBDPuerto.Text);
    md.bd.Protocol := txtBDProtocolo.Text;
    try
      md.bd.Connect;
    except
      on e : exception do
      begin
        MessageDlg ('No se ha podido conectar con el servidor: [' + txtBDServidor.Text +
            ']. Compruebe que el servicio de MySQL está iniciado y que ha ' +
            'escrito correctamente el nombre-ip del servidor.' + chr(13) + chr(13) +
            'A continuación la descripción completa del error:' + chr(13) +
            e.ClassName + chr(13) + e.Message,
            mtError, [mbok], 0);
        Exit;
      end;
    end;
 

 

Con un formulario como el siguiente, de Inicio de Sesión, para personalizar los datos de conexión a MySQL:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Ventana de inicio de sesión

 

La aplicación en funcionamiento

  • Script de creación de tablas MySQL de la aplicación:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Script creación tablas

  • Variables de MySQL Server:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Variables

  • Eliminación de registros de las tablas seleccionadas:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Vaciar tablas

  • Cambio de tipo de tabla a InnoDB:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Tipo de BD

  • Optimización de tablas:

Ventana para añadir a aplicación con utilidades de base de datos MySQL en Delphi - Optimizar tablas

ANEXO

Código fuente completo de la ventana UtilidadesBD

Aunque hemos añadido una descarga con el código fuente completo de este módulo, os lo mostramos aquí para que podáis elegir qué utilizar para vuestras aplicaciones:

unit UnidadUtilidadesBD;

interface

uses
  Windows, Messages, SysUtils, Variants,
  Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Buttons, ComCtrls;

type
  TformUtilidadesBD = class(TForm)
    tab: TPageControl;
    tabSQLCreacion: TTabSheet;
    tabOptimizar: TTabSheet;
    bCerrar: TBitBtn;
    bObtenerScript: TBitBtn;
    mScripCreacion: TRichEdit;
    bObtenerNombreTablas: TBitBtn;
    bGuardarRScript: TBitBtn;
    dlGuardar: TSaveDialog;
    bVariables: TBitBtn;
    BitBtn1: TBitBtn;
    BitBtn2: TBitBtn;
    BitBtn3: TBitBtn;
    mResultadoOptimizar: TMemo;
    bOptimizar: TBitBtn;
    tabAnalizar: TTabSheet;
    BitBtn4: TBitBtn;
    mResultadoAnalizar: TMemo;
    bCatalogos: TBitBtn;
    TabSheet1: TTabSheet;
    bMostrarTablas: TBitBtn;
    opReiniciarContador: TCheckBox;
    bEliminarContenido: TBitBtn;
    StaticText1: TStaticText;
    lsTablas: TListBox;
    Label1: TLabel;
    TabSheet2: TTabSheet;
    bCambiarTipo: TBitBtn;
    bMostrarTablas2: TBitBtn;
    lsTablas2: TListBox;
    Label2: TLabel;
    lsTipoBD: TComboBox;
    Label3: TLabel;
    bpTipo: TProgressBar;
    procedure bObtenerScriptClick(Sender: TObject);
    procedure bObtenerNombreTablasClick(Sender: TObject);
    procedure bGuardarRScriptClick(Sender: TObject);
    procedure bVariablesClick(Sender: TObject);
    procedure BitBtn1Click(Sender: TObject);
    procedure BitBtn2Click(Sender: TObject);
    procedure BitBtn3Click(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure BitBtn4Click(Sender: TObject);
    procedure bCatalogosClick(Sender: TObject);
    procedure bOptimizarClick(Sender: TObject);
    procedure bCerrarClick(Sender: TObject);
    procedure FormClose(Sender: TObject;
        var Action: TCloseAction);
    procedure bEliminarContenidoClick(Sender: TObject);
    procedure bMostrarTablasClick(Sender: TObject);
    procedure bMostrarTablas2Click(Sender: TObject);
    procedure bCambiarTipoClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  formUtilidadesBD: TformUtilidadesBD;

implementation

uses UnidadModuloDatos, DB;

{$R *.dfm}

procedure TformUtilidadesBD.bObtenerScriptClick(
    Sender: TObject);
begin
  mScripCreacion.Lines.Clear;
  md.tc2.Close;
  md.tc2.SQL.Clear;
  md.tc2.SQL.Add('show tables');
  md.tc2.Open;
  while not md.tc2.Eof do
  begin
    md.tc.Close;
    md.tc.SQL.Clear;
    md.tc.SQL.Add('show create table ' +
        md.tc2.Fields.Fields[0].AsString);
    md.tc.Open;
    mScripCreacion.Lines.Add('');
    mScripCreacion.Lines.Add('');    
    mScripCreacion.Lines.Add(md.tc.Fields.Fields[1].AsString);
    md.tc2.Next;
  end;
  md.tc2.close;
  md.tc.Close;
end;

procedure TformUtilidadesBD.bObtenerNombreTablasClick(
    Sender: TObject);
begin
  mScripCreacion.Lines.Clear;
  md.tc2.Close;
  md.tc2.SQL.Clear;
  md.tc2.SQL.Add('show tables');
  md.tc2.Open;
  while not md.tc2.Eof do
  begin
    mScripCreacion.Lines.Add(
        md.tc2.Fields.Fields[0].AsString);
    md.tc2.Next;
  end;
  md.tc2.close;
end;

procedure TformUtilidadesBD.bGuardarRScriptClick(
    Sender: TObject);
begin
  dlGuardar.Title := 'Guardar resultado Script-Tablas';
  dlGuardar.Filter := 'Archivo de texto (*.txt)|*.txt|' +
      'Script SQL (*.sql)|*.sql|Todos los archivos|*.*';
  dlGuardar.DefaultExt := 'txt';
  if dlGuardar.Execute then
    mScripCreacion.Lines.SaveToFile(dlGuardar.FileName);
end;

procedure TformUtilidadesBD.bVariablesClick(Sender: TObject);
begin
  mScripCreacion.Lines.Clear;
  md.tc2.Close;
  md.tc2.SQL.Clear;
  md.tc2.SQL.Add('show variables');
  md.tc2.Open;
  while not md.tc2.Eof do
  begin
    mScripCreacion.Lines.Add(md.tc2.Fields.Fields[0].AsString +
        ' = ' + md.tc2.Fields.Fields[1].AsString);
    md.tc2.Next;
  end;
  md.tc2.close;
end;

procedure TformUtilidadesBD.BitBtn1Click(Sender: TObject);
var
 campo, tipo, nulo, clave, defecto, extra : string;
begin
  mScripCreacion.Lines.Clear;
  md.tc2.Close;
  md.tc2.SQL.Clear;
  md.tc2.SQL.Add('show tables');
  md.tc2.Open;
  while not md.tc2.Eof do
  begin
    md.tc.Close;
    md.tc.SQL.Clear;
    md.tc.SQL.Add('desc ' + md.tc2.Fields.Fields[0].AsString);
    md.tc.Open;
    mScripCreacion.Lines.Add('');
    mScripCreacion.Lines.Add('');
    mScripCreacion.Lines.Add(md.tc2.Fields.Fields[0].AsString);
    while not md.tc.Eof do
    begin
      campo := md.tc.fieldbyname('field').AsString;
      tipo := md.tc.fieldbyname('type').AsString;
      nulo := md.tc.fieldbyname('null').AsString;
      clave := md.tc.fieldbyname('key').AsString;
      defecto := md.tc.fieldbyname('default').AsString;
      extra := md.tc.fieldbyname('extra').AsString;
      mScripCreacion.Lines.Add('[' + campo + ']' + '
          [' + tipo + ']  ' +
          '[' + nulo + ']  ' + '[' + clave + ']  ' +
          '[' + defecto + ']  ' +
          '[' + extra + ']');
      md.tc.Next;
    end;
    md.tc2.Next;
  end;
  md.tc2.close;
  md.tc.Close;
end;

procedure TformUtilidadesBD.BitBtn2Click(
    Sender: TObject);
var
  nombre, engine, fechacreacion, collation : string;
  tamano, rows, tamanoIndice, tamanoTotal,
  tamanoTotalIndice, rowsTotales : Double;
begin
  mScripCreacion.Lines.Clear;
  tamanoTotal := 0;
  rowsTotales := 0;
  tamanoTotalIndice := 0;
  md.tc.Close;
  md.tc.SQL.Clear;
  md.tc.SQL.Add('show table status');
  md.tc.Open;
  mScripCreacion.Lines.Add('');
  mScripCreacion.Lines.Add('');
  while not md.tc.Eof do
  begin
    nombre := md.tc.fieldbyname('name').AsString;
    engine :=
        md.tc.fieldbyname('engine').AsString;
    rows := md.tc.fieldbyname('rows').AsFloat;
    rowsTotales := rowsTotales + rows;
    tamano :=
        md.tc.fieldbyname('data_length').AsFloat;
    tamanoTotal := tamanoTotal + tamano;
    tamanoIndice :=
        md.tc.fieldbyname('index_length').AsFloat;
    tamanoTotalIndice :=
        tamanoTotalIndice + tamanoIndice;
    fechacreacion :=
        md.tc.fieldbyname('create_time').AsString;
    collation := md.tc.fieldbyname('collation').AsString;
    mScripCreacion.Lines.Add('[' +
        nombre + ']' + '  [' + engine + ']  ' +
        '[' + FloatToStr (rows) + ']  ' + '[' +
        FloatToStr(tamano) + ']  ' +
        '[' + FloatToStr (tamanoIndice) + ']  ' +
        '[' + fechacreacion + ']' +
        '[' + collation + ']');
    md.tc.Next;
  end;
  mScripCreacion.Lines.Add('');
  mScripCreacion.Lines.Add('');
  mScripCreacion.Lines.Add('');
  mScripCreacion.Lines.Add('------------ TOTALES -----------');
  mScripCreacion.Lines.Add('Tamaño total datos: ' +
      FloatToStr(tamanoTotal));
  mScripCreacion.Lines.Add('Tamaño total índices: ' +
      FloatToStr(tamanoTotalIndice));
  mScripCreacion.Lines.Add('Filas totales: ' +
      FloatToStr(rowsTotales));
  md.tc.Close;
end;

procedure TformUtilidadesBD.BitBtn3Click(Sender: TObject);
begin
  mScripCreacion.Lines.Clear;
  md.tc2.Close;
  md.tc2.SQL.Clear;
  md.tc2.SQL.Add('show status');
  md.tc2.Open;
  while not md.tc2.Eof do
  begin
    mScripCreacion.Lines.Add(md.tc2.Fields.Fields[0].AsString +
        ' = ' + md.tc2.Fields.Fields[1].AsString);
    md.tc2.Next;
  end;
  md.tc2.close;
end;

procedure TformUtilidadesBD.FormShow(Sender: TObject);
begin
  tabSQLCreacion.Show;
end;

procedure TformUtilidadesBD.BitBtn4Click(
    Sender: TObject);
begin
  mResultadoAnalizar.Lines.Clear;
  md.tc2.Close;
  md.tc2.SQL.Clear;
  md.tc2.SQL.Add('show tables');
  md.tc2.Open;
  while not md.tc2.Eof do
  begin
    md.tc.Close;
    md.tc.SQL.Clear;
    md.tc.SQL.Add('analyze table ' +
        md.tc2.Fields.Fields[0].AsString);
    md.tc.Open;
    mResultadoAnalizar.Lines.Add(
        md.tc.Fields.Fields[0].AsString + ' ' +
        md.tc.Fields.Fields[2].AsString + ' ' +
        md.tc.Fields.Fields[3].AsString);
    md.tc2.Next;
  end;
  md.tc2.close;
  md.tc.Close;
end;

procedure TformUtilidadesBD.bCatalogosClick(
    Sender: TObject);
begin

  mScripCreacion.Lines.Clear;
  md.tc2.Close;
  md.tc2.SQL.Clear;
  md.tc2.SQL.Add('show databases');
  md.tc2.Open;
  while not md.tc2.Eof do
  begin
    mScripCreacion.Lines.Add(
        md.tc2.Fields.Fields[0].AsString);
    md.tc2.Next;
  end;
  md.tc2.close;
end;

procedure TformUtilidadesBD.bOptimizarClick(
    Sender: TObject);
begin
  mResultadoOptimizar.Lines.Clear;
  md.tc2.Close;
  md.tc2.SQL.Clear;
  md.tc2.SQL.Add('show tables');
  md.tc2.Open;
  while not md.tc2.Eof do
  begin
    md.tc.Close;
    md.tc.SQL.Clear;
    md.tc.SQL.Add('optimize table ' +
        md.tc2.Fields.Fields[0].AsString);
    md.tc.Open;
    mResultadoOptimizar.Lines.Add(
        md.tc.Fields.Fields[0].AsString + ' ' +
        md.tc.Fields.Fields[2].AsString + ' ' +
        md.tc.Fields.Fields[3].AsString);
    md.tc2.Next;
  end;
  md.tc2.close;
  md.tc.Close;
end;

procedure TformUtilidadesBD.bCerrarClick(
    Sender: TObject);
begin
  close;
end;

procedure TformUtilidadesBD.FormClose(
    Sender: TObject;
  var Action: TCloseAction);
begin
  Action := caFree;
end;

procedure TformUtilidadesBD.bEliminarContenidoClick(
    Sender: TObject);
var
  i : integer;
  nombreTablasEliminar : string;
begin
  if MessageDlg('¿Está seguro que desea eliminar' +
      ' el contenido de ' +
      inttostr(lsTablas.SelCount) + ' tablas?',
      mtConfirmation, [mbno, mbyes], 0) = mryes then
  begin
    for i := 0 to lsTablas.Count - 1 do
    begin
      if lsTablas.Selected[i] then
        if nombreTablasEliminar = '' then
          nombreTablasEliminar := lsTablas.Items[i]
        else
          nombreTablasEliminar :=
              nombreTablasEliminar + ', ' +
              lsTablas.Items[i];
    end;
    if MessageDlg('Se va a eliminar el contenido de ' +
        'las siguientes tablas: ' +
        nombreTablasEliminar + '.' + chr(13) +
        chr(13) +
        ' · Pulse "No" para continuar. ' + chr(13) +
        ' · Pulse "Sí" para anular el proceso.',
        mtConfirmation,
        [mbyes, mbno], 0) = mrno then
    begin
      for i := 0 to lsTablas.Count - 1 do
      begin
        if lsTablas.Selected[i] then
        begin
          md.tc2.Close;
          md.tc2.SQL.Clear;
          md.tc2.SQL.Add('truncate table ' +
              lsTablas.Items[i]);
          md.tc2.ExecSQL;
          md.tc2.close;
          if opReiniciarContador.Checked then
          begin
            md.tc2.Close;
            md.tc2.SQL.Clear;
            md.tc2.SQL.Add('ALTER TABLE ' +
                lsTablas.Items[i] +
                ' AUTO_INCREMENT = 1;');
            md.tc2.ExecSQL;
            md.tc2.close;
          end;
        end;
      end;
      MessageDlg('Se ha eliminado el contenido de las ' +
          'tablas seleccionadas correctamente.',
          mtInformation, [mbok], 0);
    end;
  end;
end;

procedure TformUtilidadesBD.bMostrarTablasClick(
    Sender: TObject);
begin
  lsTablas.Clear;
  md.tc2.Close;
  md.tc2.SQL.Clear;
  md.tc2.SQL.Add('show tables');
  md.tc2.Open;
  while not md.tc2.Eof do
  begin
    lsTablas.Items.Add(
        md.tc2.Fields.Fields[0].AsString);
    md.tc2.Next;
  end;
  md.tc2.close;
end;

procedure TformUtilidadesBD.bMostrarTablas2Click(
    Sender: TObject);
begin
  lsTablas2.Clear;
  md.tc2.Close;
  md.tc2.SQL.Clear;
  md.tc2.SQL.Add('show tables');
  md.tc2.Open;
  while not md.tc2.Eof do
  begin
    lsTablas2.Items.Add(
        md.tc2.Fields.Fields[0].AsString);
    md.tc2.Next;
  end;
  md.tc2.close;
end;

procedure TformUtilidadesBD.bCambiarTipoClick(
    Sender: TObject);
var
  i, numTablas : integer;
  nombreTablasCambiar, tipoTabla : string;
begin
  bpTipo.Position := 0;
  bpTipo.Min := 0;
  tipoTabla := lsTipoBD.Text;
  if tipoTabla = '' then
  begin
    MessageDlg ('Debe indicar el nuevo tipo de tabla.',
        mtInformation, [mbok], 0);
    lsTipoBD.SetFocus;
  end
  else
  begin
    if MessageDlg('¿Está seguro que desea cambiar el tipo de ' +
        inttostr(lsTablas2.SelCount) + ' tablas?',
        mtConfirmation, [mbno, mbyes], 0) = mryes then
    begin
      numTablas := lsTablas2.Count;
      for i := 0 to numTablas - 1 do
      begin
        if lsTablas2.Selected[i] then
          if nombreTablasCambiar = '' then
            nombreTablasCambiar := lsTablas2.Items[i]
          else
            nombreTablasCambiar := nombreTablasCambiar + ', ' +
                lsTablas2.Items[i];
      end;
      if MessageDlg('Se va a cambiar el tipo de las ' +
          'siguientes tablas: ' +
          nombreTablasCambiar + '.' + chr(13) + chr(13) +
          ' · Pulse "No" para continuar. ' + chr(13) +
          ' · Pulse "Sí" para anular el proceso.',
          mtConfirmation,
          [mbyes, mbno], 0) = mrno then
      begin
        bpTipo.Max := lsTablas2.SelCount - 1;
        for i := 0 to numTablas - 1 do
        begin
          bpTipo.Position := i;        
          if lsTablas2.Selected[i] then
          begin
            md.tc2.Close;
            md.tc2.SQL.Clear;
            md.tc2.SQL.Add('ALTER TABLE ' +
                lsTablas2.Items[i] + ' ENGINE = ' + tipoTabla);
            md.tc2.ExecSQL;
            md.tc2.close;
          end;
        end;
        MessageDlg('El proceso ha finalizado correctamente.',
            mtInformation, [mbok], 0);
      end;
    end;
  end;
end;

end.
 

Artículos relacionados

 

Créditos

Artículo realizado íntegramente por Alonsojpd, miembro fundador del proyecto AjpdSoft.


Anuncios


Enviado el Lunes, 02 febrero a las 11:45:17 por ajpdsoft
Este sitio web NO CONTIENE malware, todos los programas con código fuente aquí. Autor: Alonso Javier Pérez Díaz Google+ Síguenos en Google+